Signal-Übertragung eines Rechteckpulses

Definieren wir eine Rechteckfunktion in der Zeit t, welche um den Zeitpunkt t = 0 zentriert ist :

f[t_,τ_]:=5*HeavisideTheta[τ/2-t]*HeavisideTheta[t+τ/2]

Sei z.B. t eine Zeit in µs. Dann ist dies ein 1 µs kurzer Rechteckpuls (z.B. ein TTL-Signal mit Spannung 5 V).

Plot[f[t,1], {t, -2, 2}, AxesLabel->{"t / µs", "U / V"}]

Die Fourier-Transformierte von f ist das (Kreis-) Frequenzspektrum aller zu f beitragender harmonischer Schwingungen :

p[ω_, τ_]=FourierTransform[f[t,τ], t, ω]

Je kürzer der TTL-Puls (also je kleiner τ) desto "breiter" ist das Frequenzspektrum der beteiligten harmonischen Schwingungen :

Plot[p[ω,1], {ω, -30,30}, PlotRange->All, AxesLabel->{"ω / MHz","U / V"}]

Nehmen wir nun an, wir schicken das Signal durch einen Verstärker mit einem bestimmten Frequenzgang. Der Einfachheit halber gehen wir von einer beliebig scharfen Grenzfrequenz g und einem Verstärkungsfaktor von 10 aus.

frequenzgang[ω_, g_]:=10*HeavisideTheta[g-ω]*HeavisideTheta[g+ω]

Plot[frequenzgang[ω,12], {ω, -30, 30}, AxesLabel->{"ω / MHz","Verstärkung"}]

Dieser Verstärker lässt nur Harmonische passieren, deren Kreisfrequenz absolut kleiner als die Grenzfrequenz g ist. Das verstärkte Spektrum sieht also so aus :

Plot[frequenzgang[ω,12]*p[ω,1], {ω, -30, 30}, PlotRange->All,AxesLabel->{"ω / MHz","U / V"} ]

Beobachtet man nun das verstärkte Signal im Zeitraum (z.B. mit einem Oszilloskop) so sieht man die Fourier(-Rück-)Transformierte dieses durch die Grenzfrequenz g veränderten Spektrums:

v[t_, τ_, g_]=InverseFourierTransform[frequenzgang[ω,g]*p[ω,τ], ω, t]

Wie man sieht ist der verstärkte Puls trotz aller Vereinfachungen bereits eine sehr komplizierte Funktion. Im Allgemeinen lassen sich Fourier-Transformationen von Signalformen nur numerisch durchführen.

Für einen Verstärker mit sehr großer Bandbreite (z.B. g = 10 GHz) wird der 1 µs kurze Rechteckpuls fast unverformt übertragen. Senkt man die Bandbreite, kommt es zunehmend zu "Überschwingern" an den Sprungstellen des Pulses, weil die zur Reproduktion der scharfen Kanten nötigen hohen Schwingungsfrequenzen fehlen. Benutzt man ein zu schmalbandiges Übertragungssystem (z.B. g = 20-MHz), ist der Rechteckpuls kaum noch als solcher zu erkennen.

Plot[v[t,1,10000], {t, -2, 2},AxesLabel->{"t / µs", "U / V"}]